project('tdd-in-c', 'c')

cgreen_dep = dependency('cgreen')
cgreen_runner = find_program('cgreen-runner')

inc_dir = include_directories('inc')

my_fancy_calculator_lib = library('my_fancy_calculator',
    'src/my_fancy_calculator.c',
    include_directories: inc_dir)

my_fancy_calculator_dep = declare_dependency(
    link_with: my_fancy_calculator_lib,
    include_directories: inc_dir)

executable('demo',
    'src/main.c',
    dependencies: [my_fancy_calculator_dep])


test_lib = library('demo_test',
    'test/my_fancy_test.c',
    dependencies: [cgreen_dep, my_fancy_calculator_dep])

test('my_fancy_test', cgreen_runner, args: test_lib, verbose: true)


cmake = import('cmake')
paho = cmake.subproject('paho')
# message('CMaket targets:\n - ' + '\n - '.join(paho.target_list()))
paho_dep = paho.dependency('paho-mqtt3c')

mqtt_example_lib = library('mqtt_example',
    'src/mqtt_example.c',
    include_directories: inc_dir,
    dependencies: paho_dep)

mqtt_example_dep = declare_dependency(
    link_with: mqtt_example_lib,
    include_directories: inc_dir)

mqtt_test_lib = library('mqtt_example_test',
    'test/mqtt_example_test.c',
    dependencies: [cgreen_dep, mqtt_example_dep, paho_dep])

test('mqtt_example_test', cgreen_runner, args: mqtt_test_lib, verbose: true)